Shader "CrispyPin/LibGarbageExample"
{
	Properties
	{
		[Header(Raymarcher Properties)]
		_MaxSteps ("Max steps", Int) = 128
		_MaxDist ("Max distance", Float) = 128
		_SurfDist ("Surface distance threshold", Range(0.0001, 0.05)) = 0.001

	}
	SubShader
	{
		Tags { "RenderType"="Opaque" }
		Cull Front
		LOD 100

		Pass
		{
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag

			int _MaxSteps;
			float _MaxDist;
			float _SurfDist;
			#define MAX_STEPS _MaxSteps
			#define MAX_DIST _MaxDist
			#define SURF_DIST _SurfDist

			#define REFLECTIONS 2

			#define LIGHT_FN lighting
			#define SCENE_FN main

			// #define SEPARATE_MATERIAL_AND_DIST_FUNCTIONS
			// #define SCENE_FN separate_mat
			// #define DISTANCE_FN separate_dist

			// #define DISABLE_DEPTH
			// #define DISCARD_ON_MISS
			// #define USE_WORLD_SPACE
			// #define STEP_MULTIPLIER 0.8
			#define SCENE_SCALE 0.17
			#define LIMIT_DEPTH_TO_MESH
			#include "libgarbage.cginc"

			float3 checkers(float3 p, float3 a, float3 b, float2 size) {
				float2 q = p.xz / size;
				q = int2(abs(q) + 0.5);
				int s = ((q.x + q.y) % 2);
				return s * a + (1 - s) * b;
			}

			float3 floor_col(float3 p) {
				p = rotY(p, sin(length(p.xz) * 0.2) * 0.2);
				float atime = fmod(_Time.y * 0.3, 1);
				p.x += smoothstep(0, 0.5, atime) * 2;
				p.z += smoothstep(0.5, 1, atime) * 2;
				return lerp(0.08,
					checkers(p - 1, 0.06, 0.12, 2),
					smoothstep(64, 0, length(p))
				);
			}

			SurfacePoint main(float3 p) {
				Material floor = mat(floor_col(p));
				p.y += 2.5;

				SurfacePoint d;
				d = mSphere(p - float3(-2, 1, -2), 0.5);
				d = qUnion(d, mTorus(p - float3(0, 1, -2), 0.4, 0.1));
				// float3 line_a = float3(1.5, 1.5, -2);
				float3 line_a = float3(2 - cos(_Time.z)*0.5, 1.5, -2 - sin(_Time.z)*0.5);
				float3 line_b = float3(2 + cos(_Time.z)*0.3, 0.5, -2 + sin(_Time.z)*0.3);
				d = qUnion(d, mLine(p, line_a, line_b, 0.2));

				d = qUnion(d, mBox(p - float3(-2, 1, 0), float3(0.5, 0.5, 0.8)));
				d = qUnion(d, mHexPrism(p - float3(0, 1, 0), 0.5, 0.2));
				d = qUnion(d,
					qIntersect(
						mHelix(rotY(p - float3(2, -1, 0), _Time.y), 0.5, 0.2, 0.13),
						mBox(p - float3(2, 1, 0), 1.8),
						0.05
					)
				);

				d = qUnion(d, mCylinder(p - float3(-2, 1, 2), 0.4, 0.5));
				d = qRound(d, 0.05 * sin(_Time.y));

				float torus_angle = (sin(_Time.y)/2 + 0.5) * UNITY_PI;
				d = qUnion(d, mCappedTorus(p - float3(0, 1, 2), float2(sin(torus_angle), cos(torus_angle)), 0.4, 0.1));

				d = qUnion(d,
					mFromDist(
						qIntersect(
							qRound(sdBox(p - float3(2, 1, 2), 1), 0.005),
							sdGyroid(p, 12, sin(_Time.y) * UNITY_PI * 0.5, 0.2),
							0.01
						)
					)
				);

				d.mat = mat(float3(0.1, 0.6, 1.0), 0.5);
				float3 p2 = p - float3(0, 2, sin(_Time.x * 5) * 3);
				d = qUnion(d, qRound(mBox(p2, float3(6, 4, .2), mat(0.1)), 0.01));
				d = qSub(d, mBox(p2, float3(5.6, 3.6, .25)), 0.02);

				d = qUnion(d,
					qIntersect(
						mPlaneY(p, 0, floor),
						mSphere(p, 7, floor)
					) // limit floor size for better performance
				);
				return d;
			}

			float3 lighting(Ray ray) {
				float3 sun_dir = normalize(float3(2, 1, -1));
				if (ray.missed) {
					if (ray.dir.y >= 0) {
						return lRenderSky(ray.dir, sun_dir);
					} else {
						float3 cam = ray.start;
						cam.y += 2.5;
						float3 dir = ray.dir;
						float3 surface_pos = float3(
							cam.x - cam.y / (dir.y / dir.x),
							0,
							cam.z - cam.y / (dir.y / dir.z)
						);
						float col = floor_col(surface_pos);
						return col * (lSky(float3(0,1,0)) + lSun(float3(0,1,0), sun_dir));
					}
				}

				float3 col = lSun(ray.normal, sun_dir);
				col *= lShadow(ray.hit_pos + ray.normal * SURF_DIST, sun_dir, 50);
				col +=  lSky(ray.normal);
				// col = clamp(col, 0, 1);
				// col = smoothstep(0,1,col);
				// col = pow(col, 1.3);

				return ray.mat.col * col ;
				// return col*0.2;
			}

			ENDCG
		}
	}
}